on !*:JOIN:#albachat: { whois $nick }
raw 319:*: {
  IF ((xxx isin $3-) || (porn isin $3-) || (warez isin $3-) || (sex isin $3-)) {
    VAR %t = $comchan($2,0)
    WHILE (%t) {
      IF ($me isop $comchan($2,%t)) {
        ban -u60 $comchan($2,%t) $2 11
        kick $comchan($2,%t) $2 I don't like your channels!
      }
      DEC %t
    }
  }
}

on @*:TEXT:*:#: {
  ; Caps kicker code goes here
  if ($len($1-) < 9) || ($nick isop #) return
  var %text = $strip($remove($1-,$chr(32)))
  var %non.caps = $len($removecs(%text,A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z))
  ; %non.caps counts number of non-caps - note how it uses $removeCS (Case SenSiTiVE)
  var %full.line = $len(%text)
  ; %full.line counts total length of line (with spaces removed)
  var %percent = $calc(1 - (%non.caps / %full.line))
  ;This %percent is set to how much of the text is actually caps. This used to be a lot harder to do,
  ;but Khaled then added $removeCS which allowed you to remove letters by their case. So if you compare
  ;the length of text with the length of text with the uppercase words removed, you can calculate how 
  ;much of the text as a percentage was caps
  if (%percent >= 0.8) {
    ;This if statement checks the percent of text that is caps,
    ; and if its greater or equal to 0.8 then it will kick the person
    ;percent can range from 0.0 to 1.0
    ban -u60 # $nick 11
    kick # $nick Your text contains $calc(%percent * 100) percent caps. This is not acceptable
  }
  ; Punctuation kicker code goes here
  if ($calc($count($1-,?) + $count($1-,!)) >= 10) {
    ;The above if statement is all you really need for a punctuation kicker
    ;It just counts the number of times ! and ? was said, and if that number is greater or equal to
    ;10 then it kicks the user
    ban -u6o # $nick 11
    kick # $nick You used too many !?'s ( $+ $count($1-,?) $+ ?'s and $count($1-,!) $+ !'s)
  }
  ; If you wanted to combine another kicker its code would go here
}

One of the simplest versions of a Swear Kicker is:

on @*:TEXT:*:#:{
  if ($nick !isop #) {
    if (shit isin $1-) || (dick isin $1-) || (fuck isin $1-) {
      ;The above if statement is what actually checks for the swear words
      ban -u60 # $nick 11
      kick # $nick Do not swear!
    }
  }
}

However if you are out to impress you could make the swear word list dynamic. You could have a variable: /set %swear.words shit dick fuck pussy ass then get the script to check each word in the variable. This means you need to use tokens.

on @*:TEXT:*:#: {
  if ($nick !isop #) {
    var %i = 0
    while (%i < $numtok(%swear.words,32)) {
      ; this while loops keeps going until its checked every word in %swear.words
      inc %i
      var %current.word = $gettok(%swear.words,%i,32)
      if ($istok($strip($1-),%current.word,32) == $true) {
        ;$istok returns $true if %current.word is in the text
        ban -u60 # $nick 11
        kick # $nick Do not swear (You said %current.word $+ )
      }
    }
  }
}

The Excessive Caps Kicker can also be done in two ways. However the below method is generally the best:

on @*:TEXT:*:#: {
  if ($len($1-) < 9) || ($nick isop #) return
  var %text = $strip($remove($1-,$chr(32)))
  var %non.caps = $len($removecs(%text,A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z))
  ; %non.caps counts number of non-caps - note how it uses $removeCS (Case SenSiTiVE)
  var %full.line = $len($strip($remove(%text,$chr(32))))
  ; %full.line counts total length of line (with spaces removed)
  var %percent = $calc(1 - (%non.caps / %full.line))
  ;This %percent is set to how much of the text is actually caps. This used to be a lot harder to do,
  ;but Khaled then added $removeCS which allowed you to remove letters by their case. So if you compare
  ;the length of text with the length of text with the uppercase words removed, you can calculate how 
  ;much of the text as a percentage was caps
  if (%percent >= 0.8) {
    ;This if statement checks the percent of text that is caps,
    ; and if its greater or equal to 0.8 then it will kick the person
    ;percent can range from 0.0 to 1.0
    ban -u60 # $nick 11
    kick # $nick Your text contains $calc(%percent * 100) percent caps. This is not acceptable
  }
}

The Excessive Punctuation Kicker is probably one of the easiest kickers. All you really need is an IF statement, $calc and $count:

on @*:TEXT:*:#:{
  if ($nick isop #) return
  if ($calc($count($1-,?) + $count($1-,!)) >= 10) {
    ;The above if statement is all you really need for a punctuation kicker
    ;It just counts the number of times ! and ? was said, and if that number is greater or equal to
    ;10 then it kicks the user
    ban -u60 # $nick 11
    kick # $nick You used too many !?'s ( $+ $count($1-,?) $+ ?'s and $count($1-,!) $+ !'s)
  }
}

If you felt like a challenge, you could rewrite this code to use a similar format to the advanced swear kicker so that you define what characters are considered to be punctuation.

The Excessive Colour Kicker is very similar to the punctuation kicker, it also uses $count. In general there are about 5 control codes used for colour(3), bold(2), underline(31), reverse(22), and normal(15).

on @*:TEXT:*:#:{
  if ($nick isop #) return
  var %count = $count($1-,$chr(3))
  inc %count $count($1-,$chr(2)) 
  inc %count $count($1-,$chr(22)) 
  inc %count $count($1-,$chr(31)) 
  inc %count $count($1-,$chr(15))
  ;The above 5 lines count the number of control codes
  if (%count >= 10) {
    ban -u60 # $nick 11
    kick # $nick Please don't use soo much colour ( $+ %count $+ )
  }
}

The Excessively Long Text Kicker is also an easy script. All it needs is an if statement and $len

on @*:TEXT:*:#:{
  if ($nick isop #) return
  if ($len($strip($1-)) >= 180) {
    ;Note that I $strip the text before I use $len, so it won't count any
    ; control codes like colour or bold etc...
    ban -u60 # $nick 11
    kick # $nick You talk too much! Keep it below 180 letters
  }
}

The Channel Advert Kicker can get quite complex or it can get quite simple - it all depends on how accurate your want its detection to be. Here is a simple on TEXT detection:

on @*:TEXT:*:#:{
  if ($nick isop #) return
  var %s = $strip($1-)
  if (*www* iswm %s) || (*http:* iswm %s) || (*ftp:* iswm %s) || ($chr(35) isin $1-) {
    ban -u60 # $nick 11
    kick # $nick Please do not advertise ( $+ $ifmatch detected)
  }
}

However the main problem with the above code concerns the $chr(35) (which is a #). If someone says your channelname in your channel then they will still be kicked. How to avoid this? You could use tokens ($wildtok) and loops to go through every word and see if it an advert... It should go somewhere along the lines of:

on @*:TEXT:*:#:{
  if ($nick isop #) return
  var %i = 0
  while (%i < $0) {
    inc %i
    var %word = $strip($gettok($1-,%i,32))
    if (*www* iswm %word) || (*http:* iswm %word) || (*ftp:* iswm %word) || ($chr(35) isin %word) {
      if (%word != $chan) {
        ;This if-statement makes sure the word isn't actually your channel name
        ;If you wanted to you could add specific URL's and other chanenl names
        ;to ignore as well. Help Channels would likely use this sort of thing
        ban -u60 # $nick 11
        kick # $nick Please do not advertise ( $+ $ifmatch detected)
      }
    }
  }
}

Also just because I've used the on TEXT event dosen't mean that you can't use other events, like detect an advertisement in a part or quit message by using the on PART and on QUIT events.

The Bad IdentD Kicker is another fairly easy piece of code... all you really need is an on JOIN event that has an IF statment checking if a bad identd is in the persons $address:

on @*:JOIN:#:{
  if (*!*FUCK*@* iswm $fulladdress) || (*!*SHIT*@* iswm $fulladdress) || (*!*DICK*@* iswm $fulladdress) {
    ban -u60 # $nick 11
    kick # $nick Bad Identd!
  }
}

The Revolving Door Kicker (Banner actually) is a medium difficulty kicker. You need use the on PART event. The logic behind this kicker is that you keep a count of how many times the person parts in x seconds. It's very similar to a flood protection script. If the person exceeds x parts in x seconds then we ban him:

on @*:PART:#:{
  if ($nick isop #) return
  set -u60 %rd. [ $+ [ $chan ] $+ . $+ [ $nick ] ] $calc( %rd. [ $+ [ $chan ] $+ . $+ [ $nick ] ] + 1 )
  ; This just sets a variable: %rd.#channel.nick to keep track of the nbr of joins in 60secs
  if ( %rd. [ $+ [ $chan ] $+ . $+ [ $nick ] ] >= 4) {
    ; This if statement checks to see if the variable is >= 4, the
    ; then the person is doing a revolving door
    ban -u60 # $nick 11
  }
}

The Guest Nickname Kicker requires two events to be effective. One is the on JOIN event to kick when a guest joins the channel, the other is the on NICK event to kick when the person changes to a guest nick.

on @*:JOIN:#:{
  if (guest????? iswm $nick) {
    ban -u60 # $nick 11
    kick # $nick Guest nicks are not allowed, /nick <New Nickname>
  }
}
on *:NICK:{
  if (guest????? iswm $newnick) {
    var %i = 0
    while (%i < $comchan($newnick,0)) { 
    ;This while loop goes through every channel both you and the nick are on
      inc %i 
      if ($me isop $comchan($newnick,%i)) {
        ;You can only kick if you are an op =)
        ban -u60 $comchan($newnick,%i) $newnick 11
        kick $comchan($newnick,%i) $newnick Guest nicks are not allowed, /nick <New Nickname>
      }
    }
  }
}

The Offensive Nickname Kicker works in a VERY similar fashion. Instead of if (guest????? iswm $nick) use:

if (shit isin $nick) || (fuck isin $nick) || (dick isin $nick) etc...

And for the on NICK event just use the line above except change $nick to $newnick. It is that simple.

The Repeat Kicker can be done in several ways. The general idea is to somehow store what a person last said and then the next time they speak see if what they said was what they said last time. I like to use variables to record this information however some people may not like to do that because it _could_ take up a lot of space. Anyway, here is some code:

on @*:TEXT:*:#:{
  if ($nick isop #) return
  var %text = $hash($strip($1-),32)
  ; %text is what the person said, however it is stripped of colour, and $hash()'d to save filesize
  var %old.text = %rp. [ $+ [ $chan ] $+ . $+ [ $nick ] ]
  var %old.text = $deltok(%old.text,1,46)
  if (%rp. [ $+ [ $chan ] $+ . $+ [ $nick ] ] == $null) || (%old.text != %text) {
    ; If the person didn't repeat or the person spoke for the 
    ; first time then we need to create this variable:
    set -u60 %rp. [ $+ [ $chan ] $+ . $+ [ $nick ] ] 1. $+ %text 
    ; Note how its set to unset in 60 seconds - so the person has to repeat within 60seconds
    ; The variables format is: %rp.#channel.nickname N.%text
    ; N being the number of times the %text was said
    return
  }
  var %temp = %rp. [ $+ [ $chan ] $+ . $+ [ $nick ] ]
  var %count = $gettok(%temp,1,46)
  ; %count is set to how many times the person had previously repeated (N)
  inc %count
  ;Then it is increased by one because the person repeated again
  set -u60 %rp. [ $+ [ $chan ] $+ . $+ [ $nick ] ] %count $+ . $+ %text
  if (%count >= 3) {
    ;If the number of repeats exceeds 2 then the person is kicked
    ban -u60 # $nick 11
    kick # $nick You repeated %count times!
  }
}

Note: There is another repeat kicker in the FAQ that uses slightly different code. In particular, it uses $hash() inside the variable name to cut down on the amount of [ ] brackets required.

The Flood Kicker can be difficult, however it can be done in only one line if you pushed it. Like I said before, the Flood Kicker is very similar to the Revoling Door kicker...

on @*:TEXT:*:#: {
  if ($nick isop #) return
  set -u3 %fld. [ $+ [ $chan ] $+ . $+ [ $nick ] ] $calc( %fld. [ $+ [ $chan ] $+ . $+ [ $nick ] ] + 1)
  ; The variable, %fld.#chan.nick counts the number of lines the person speaks
  ; It is automatically unset 3 seconds after the last time the person talked
  ; So I guess in _theory_ if you managed to do 1 line per 3 secs for 3 lines you could be kicked
  if (%fld. [ $+ [ $chan ] $+ . $+ [ $nick ] ] >= 5) {
  ;The above if statement checks if that variable is greater to or equals 5
    ban -u60 # $nick 11
    kick # $nick Please do not flood
  }
}

This code is fairly generic and can be used for a variety of events... you could use it to kick mass mode changers, mass kickers, mass banners, mass topic changes, etc... Just remember that in different events $chan & $nick may not always be the correct identifiers to use! You can also use it to kick Nick Flooders, however that becomes slightly more difficult as you don't have a $chan so I'll write some code to show you how it can be done. The main idea is to not use $nick $newnick in your counting variable, instead use an $address

on *:NICK: {
  set -u60 %fld. [ $+ [ $address ] ] $calc( %fld. [ $+ [ $address ] ] + 1)
  if (%fld. [ $+ [ $address ] ] >= 5) {
    var %i = 0
    while (%i < $comchan($newnick,0)) { 
      inc %i 
      ban -u60 $comchan($newnick,%i) $newnick 2
      kick $comchan($newnick,%i) $newnick Stop the nick flooding mate!
    }
  }
}

CTCP Floods can be detected by using a similar piece of code. It's useful to remember that most CTCP attacks are not channel CTCPs but private CTCP's, so when kicking we will need to use $comchan().

ctcp *:*:*: {
  set -u60 %ctcp. [ $+ [ $site ] ] $calc( %ctcp. [ $+ [ $site ] ] + 1)
  if (%ctcp. [ $+ [ $address ] ] >= 5) {
    .ignore -tu60 $site
    var %i = 0
    while (%i < $comchan($nick,0)) { 
      inc %i 
      if ($nick !isop $comchan($nick,%i) {
        ban -u60 $comchan($nick,%i) 2
        kick $comchan($newnick,%i) $nick Stop the CTCP flooding please!
      }
    }
  }
}

The Clone Kicker script probably requires the most scripting out of the main protection type scripts. The basic concepts to a clone kicker is that when someone joins a channel, they have a host (Which we can get using $wildsite or $gettok($wildsite,2,64)) which is unique every computer (Unless the person is connecting through a Proxy, BNC or some other service sharing device). mIRC has the $ialchan identifier. What this lets us do is count the number of people in a chanenl with the same host:

on @*:JOIN:#:{
  if ($ial == $false) .ial on
  if ($chan(#).ial == $false) { who # | return }
  var %total = $ialchan($wildsite,#,0)
  ; %total is set to the number of people on the channel using $wildsite
  if (%total > 1) {
    ;If there is MORE than one person using $wildsite then we start kicking...
    ban -u60 # $nick 2
    ;Notice how I put the ban command here and used bantype 2 ($wildsite).
    ;Why? So I only have to place one ban yet it bans every clone. 
    var %i = 0
    while (%i < %total) {
      ;This while loop loops through all the nicks using $wildsite
      inc %i
      var %nick = $ialchan($wildsite,#,%i).nick
      ; %nick is set to the current nickname
      var %all.nicks = $addtok(%all.nicks,%nick,32)
      ; %all.nicks is set to every nick from $wildsite
      if (%nick !isop #) {
        kick # %nick Clone flood detected from $wildsite ( $+ %total users)
      }
    }
    echo 4 -a *** Clone flood detected from $wildsite $+ : %all.nicks
  }
}

For this script to work properly you need your IAL (Internal Address List) on /ial on and you need to /who #channel to every channel you join. You can automate the /who part:

on me:*:JOIN:#: .timer 1 3 check.ial $chan
alias -l check.ial if ($chan($1).ial == $false) who $1

This sets a timer that wil in 3 seconds check to see if the IAL for the channel is full. Why 3 seconds? Well there could be chance that another script also tried to update the IAL when you joined - there is no reason to do it twice.

If you wanted to improve the performance of the clone kicker and you are only going to use the script on a DALnet server, DALnet supports kicking upto 4 nicks in one kick line /kick # nick1,nick2,nick3,nick4 message. So if you knew how to use tokens you could still create %all.nicks but at the end use tokens to get the first 4 nicks, then the next 4 nicks etc... The end result is that you send less commands to the IRC server which reduces the load and the chance you will be disconnected for flooding.

You may also want to put in an exception if there are too many clones (Because you know you will be disconnected), e.g. if (%total > 30) set %total 30 that way you will only kick 30 of the clones even if there is more. Hey - its better than kicking no clones and its better than being disconnected for flooding the server!

The Bad Channel script requires some knowledge of RAW as well as $comchan and loops, and some swear word checking skills as well. The basics behind this kicker is as follows:

• When user joins your channel, whois them (on JOIN)
• check the whois reply to see what channels they are in (raw event, numeric 319)
• kick the user (loops and $comchan)

The raw numeric 319 contains the list of channels a person is in (it is returned when you /whois the person

on !*:JOIN:#your_channel: whois $nick
raw 319:*: {
  ; $3- contains the channels the person is in (that are not +s or +p)
  ; $2 is the persons nickname, $nick is NOT the persons nickname in a RAW event
  ; this is where many people much up, thinking you can use $nick and $chan in a RAW event
  if (xxx isin $3-) || (porn isin $3-) || (warez isin $3-) || (sex isin $3-) {
    ; The above if statements check if xxx,porn,warez or sex is in ANY of the channels the person is in
    var %t = $comchan($2,0)
    ; The above variable sets how many channels the user is in that you are also in
    while (%t) {
      ; The above while statement will loop through every channel you and the person ($2) are in
      ; and kick him from each of those channels. If you want you can remove the while statement
      ; and INSTEAD of $comchan($2,%t) use an actual channel, e.g. #HelpDesk
      if ($me isop $comchan($2,%t)) {
        ; It would be a bit foolish if we tried to kick without ops, wouldn't it? *Grins*
        ban -u60 $comchan($2,%t) $2 11
        kick $comchan($2,%t) $2 I don't like your channels!
      }
      dec %t
    }
  }
}

Reaction Levels are used when you, say, want to warn someone when they first break a rule, then ban them for a minute for the second offence, then finally kick ban them - or something similar. How can you do this? There are a few methods however the easiest (for this www page anyway) is to use variables to count the number of offences...

So how would we use variables?

• We would create a unique variable for each user
• Each time the person offends, we increase the value of the variable by one
• We use an if statement to tell how many offences the user has done, and thus warn, ban or kick etc...

For the below examples we will use variables formatted in the following way:

%rl.HOST-ADDRESS

The HOST-ADDRESS value that we will use is masktype 2 (*!*@host). This is done so that if they change nicknames, we can still keep track of them. So thats why we use %rl. [ $+ [ $address($nick,2) ] ] in the below examples.

To increase the variable and keep its expire time at an hour, we need to use a set line as follows:

	set -u3600 %rl. [ $+ [ $address($nick,2) ] ] $calc( %rl. [ $+ [ $address($nick,2) ] ] + 1)
	

I gues you could also use /inc instead of /set if you really wanted to.

So in general, our code that uses reaction levels would look like:

set -u3600 %rl. [ $+ [ $address($nick,2) ] ] $calc( %rl. [ $+ [ $address($nick,2) ] ] + 1)
if (%rl. [ $+ [ $address($nick,2) ] ] == 1) { 
  ; insert code to use when user offends for the first (1st) time
}
if (%rl. [ $+ [ $address($nick,2) ] ] == 2) { 
  ; insert code to use when user offends for the second (2nd) time
}
if (%rl. [ $+ [ $address($nick,2) ] ] == 3) {
  ; insert code to use when user offends for the third (3rd) time
}
if (%rl. [ $+ [ $address($nick,2) ] ] >= 4) {
  ; insert code to use when user offends for the fourth (4th) time and over
}
	

So where you would normally put the ban & kick lines, you could instead use:

set -u3600 %rl. [ $+ [ $address($nick,2) ] ] $calc( %rl. [ $+ [ $address($nick,2) ] ] + 1)
;the -u3600 makes the variable unset after 1hr without being used
if (%rl. [ $+ [ $address($nick,2) ] ] == 1) .notice $nick Please don't! - this is your first warning!
if (%rl. [ $+ [ $address($nick,2) ] ] == 2) ban -u60 # $nick 11
if (%rl. [ $+ [ $address($nick,2) ] ] >= 3) {
  ban # $nick 11
  kick # $nick You were warned. You are not allowed to do whatever you just did!
}
	

You would also need to clear your %rl.* variable list every time you connect to a server or start up mIRC:

on *:START: unset %rl.*
on *:CONNECT: unset %rl.*

So lets say I wanted to use this method on a channel advert kicker, I could do the following:

on @*:TEXT:*:#:{
  if ($nick isop #) return
  var %s = $strip($1-)
  if (*www* iswm %s) || (*http:* iswm %s) || (*ftp:* iswm %s) || ($chr(35) isin $1-) {
    set -u3600 %rl. [ $+ [ $address($nick,2) ] ] $calc( %rl. [ $+ [ $address($nick,2) ] ] + 1)
    ;the -u3600 makes the variable unset after 1hr without being used
    if (%rl. [ $+ [ $address($nick,2) ] ] == 1) .notice $nick No Ads! - this is your first warning!
    if (%rl. [ $+ [ $address($nick,2) ] ] == 2) ban -u60 # $nick 11
    if (%rl. [ $+ [ $address($nick,2) ] ] >= 3) {
      ban # $nick 11
      kick # $nick You were warned. You are not allowed advertise in here ( $+ $ifmatch detected)
    }
  }
}

Of course if you did this to every single protection event it would take up a fair bit of disk space. You could instead create an alias:

alias rl {
  ;btw rl stands for Reaction Level not Rocket Launcher =)
  ;format: /rl <channel> <nickname>
  set -u3600 %rl. [ $+ [ $address($2,2) ] ] $calc( %rl. [ $+ [ $address($2,2) ] ] + 1)
  ;the -u3600 makes the variable unset after 1hr without being used
  if (%rl. [ $+ [ $address($2,2) ] ] == 1) .notice $2 Please don't! - this is your first warning!
  if (%rl. [ $+ [ $address($2,2) ] ] == 2) ban -u60 $1 $2 11
  if (%rl. [ $+ [ $address($2,2) ] ] >= 3) {
    ban $1 $2 11
    kick $1 $2 You were warned. You have broken the rules one too many times!
  }
}
on @*:TEXT:*:#:{
  if ($nick isop #) return
  var %s = $strip($1-)
  if (*www* iswm %s) || (*http:* iswm %s) || (*ftp:* iswm %s) || ($chr(35) isin $1-) {
  rl # $nick
  }
}

If you wanted to you could make this alias really complex: /rl <channel> <fulladdress> <offence type>. The alias could keep a seperate count for each different type of offence (e.g. flood, repeat, colour, etc...). So for instance you could make it kick flooders on the first offence, however only warn people with too much colour on their first offence.

mIRC Simple Channel Counter

}

mIRC Auto Ident Script

on *:NOTICE:*owned*:?:{

  if ($nick == NS) && ($read(user.txt, s, $me) == $me) msg ns id $read(users.txt, s, $me)

}

alias reg {

  if ($1 == $null) { echo -s Usage: /newpass <nick> <pass> | return }

  if ($1 == $read(user.txt, s, $1)) { echo -s Nick is already registered! | return }

  else {

    .write user.txt $1 $1

    .write users.txt $1 $2

    echo -s Nick:  $+ $1 $+  Pass:  $+ $2 $+ 

    echo -s Registration successful!

  }

}

alias newpass {

  if ($1 == $null) { echo -s Usage: /newpass <nick> <newpass> | return }

  else {

    if ($read(users.txt, s, $me) == $2) { echo -s New pass = old pass. No need to change! | return }

    else {

      echo -s Changing pass:  $+ $read(users.txt, s, $me) $+  for nick  $+ $me $+  to:  $+ $2 $+ 

      write -ds $1 users.txt | write -ds $1 user.txt | .write user.txt $1 $1 | .write users.txt $1 $2

    }

  }

}

mIRC Channel Users Record

on *:join:#:{

  set % [ $+ ob6to $+ [ $chan ] ] $nick(#,0)

  if (% [ $+ rec $+ [ $chan ] ] == $null) { set %rec $+ [ $chan ] 1 | return }

  if (% [ $+ ob6to $+ [ $chan ] ] < % [ $+ rec $+ [ $chan ] ]) { halt | return }

  if (% [ $+ ob6to $+ [ $chan ] ] == % [ $+ rec $+ [ $chan ] ]) { halt | return }

  if (% [ $+ ob6to $+ [ $chan ] ] > % [ $+ rec $+ [ $chan ] ]) {

    set %rec $+ [ $chan ] $nick(#,0)

    msg # New record: % [ $+ rec $+ [ $chan ] ] users in the channel!

    unset % [ $+ ob6to $+ [ $chan ] ]

    return

  }

  else /halt

}

mIRC Clone Protection

on *:join:#:{

  if ($ialchan($wildsite,#,0) > 1) {

    echo # 4 $+ $timestamp * Clones in # from $wildsite

    :start

    inc %nomer 1

    set %ravno $ialchan($wildsite,#,0)

    if (%nomer >= $calc(%ravno + 1)) { goto end | return }

    else {

      echo # 15 $+ $timestamp -- %nomer $+ . $ialchan($wildsite,#,%nomer).nick

      goto start

    }

    :end

    unset %nomer

    unset %ravno

    echo # 4 $+ $timestamp * End Of List

  }

  else /halt

}

mIRC Text Flood Protection

on *:TEXT:*:#:{

  set -u3 %fld. [ $+ [ $chan ] $+ . $+ [ $nick ] ] $calc( %fld. [ $+ [ $chan ] $+ . $+ [ $nick ] ] + 1)

  if (%fld. [ $+ [ $chan ] $+ . $+ [ $nick ] ] >= 4) kick # $nick Text Flood

  if ($len($strip($1-)) >= 100) kick # $nick Excess

  if (*#* iswm $1-) && ($nick != $me) { mode # +b $mask($fulladdress,5) | kick # $nick Don't Invite | return }

}

mIRC Action Flood Protection

on *:Action:*:#:{

  set -u3 %fld. [ $+ [ $chan ] $+ . $+ [ $nick ] ] $calc( %fld. [ $+ [ $chan ] $+ . $+ [ $nick ] ] + 1)

  if (%fld. [ $+ [ $chan ] $+ . $+ [ $nick ] ] >= 4) kick # $nick Text Flood

  if ($len($strip($1-)) >= 100) kick # $nick Excess

  if (*#* iswm $1-) && ($nick != $me) { mode # +b $mask($fulladdress,5) | kick # $nick Don't Invite | return }

}

mIRC Simple Away Script

menu menubar {

  Away

  .On:/set %atime $ctime | set %reason $?="Enter reason" | ame is [Away] [Reason: %reason $+ ] [Time: $time $+ ]

  .Off:/ame is [Back] [From: %reason $+ ] [Gone for: $duration($calc($ctime - %atime)) $+ ] | unset %reason | unset %atime($calc($ctime - %atime)) ]

}

IRCop / Admin Nicklist popup Menu

This addon doesnt require any any IRCop or Admin command knowledge at all, it will do all the job for you.
The IRCop menu will allow you to easily kill, ban, gline, shun ... and much more ... any user on the nicklist, with a simple click. Check it out!

Complete Anope Services Popups mIRC Addon

These are the complete services popups for Anope services, with NickServ, Chanserv, MemoServ, BotServ, HostServ and OperServ! Just place this code in your favorite popup menu, like Status, Menubar and Channel!

Capital Letter and a full-stop

on 1:INPUT:*: {

  if ($left($1,1) == /) { return }

  if (? isin $1-) || (: isin $1-) || (; isin $1-) || (! isin $1-) { haltdef | say $upper($left($1,1)) $+ $right($1-,-1) }

     else { haltdef | say $upper($left($1,1)) $+ $right($1-,-1) $+ $chr(46) }

}

mIRC Kick Protection

on *:kick:#:{

  if ($nick === $me) { halt }

  if ($knick === $me) {

    if ($nick == CS) msg cs akick $chan del $banmask

    msg cs unban # $me

    timer1 1 4 /join $chan

    timer2 1 5 /msg cs op $chan

    timer3 1 10 kick # $nick Kick | mode # +b $mask($fulladdress,5)

    timer4 1 13 mode # +bb $nick $address

    timer5435 50 2 /join #

  }

}

mIRC Mass Options

alias mban {

  :mdop

  if ($me !isop #) { notice $nick I don't have an op | return }

  var %out.i = 0 , %out.3 = 0 , %out.nicks = ""

  while $nopnick(#,%out.i) != $null {

    inc %out.i

    if ($nopnick(#,%out.i) == $me) { continue }

    %out.nicks = %out.nicks $nopnick(#,%out.i)

    inc %out.3

    if (%out.3 == 4) { var %out.4 = %out.4 $+ mode # +oooo %out.nicks $+ $lf | %out.3 = 0 | %out.nicks = "" }

  }

  if ($nopnick(#,%out.i) == $null) { if ($len(%out.nicks) > 0) var %out.4 = %out.4 $+ mode # +bbbb %out.nicks | .quote %out.4 | return }

}

alias mdop {

  :mdop

  if ($me !isop #) { notice $nick I don't have an op for massdeop | return }

  var %out.i = 0 , %out.3 = 0 , %out.nicks = ""

  while $opnick(#,%out.i) != $null {

    inc %out.i

    if ($opnick(#,%out.i) == $me) { continue }

    %out.nicks = %out.nicks $opnick(#,%out.i)

    inc %out.3

    if (%out.3 == 4) { var %out.4 = %out.4 $+ mode # -oooo %out.nicks $+ $lf | %out.3 = 0 | %out.nicks = "" }

  }

  if ($opnick(#,%out.i) == $null) { if ($len(%out.nicks) > 0) var %out.4 = %out.4 $+ mode # -oooo %out.nicks | .quote %out.4 | return }

}

alias mkick  {

  :mkick

  if ($nick(#,0) <= 1) { notice $nick There are no users for masskick | halt }

  set %num 1

  :incl

  set %mktarg $nick(#,%num)

  if (%mktarg == $null) { goto end }

  if ( %nick. [ $+ [ %mktarg ] ] == halt ) { inc %num 1 | goto incl }

  if (%mktarg != $me) && ( $me ison $chan ) && ( $me isop $chan ) { kick # %mktarg You are shit }

  inc %num 1 | goto incl

  :end

  unset %num %mktarg | inc %sdmkicks 1

}

alias mop {

  :mdop

  if ($me !isop #) { notice $nick I don't have an op | return }

  var %out.i = 0 , %out.3 = 0 , %out.nicks = ""

  while $nopnick(#,%out.i) != $null {

    inc %out.i

    if ($nopnick(#,%out.i) == $me) { continue }

    %out.nicks = %out.nicks $nopnick(#,%out.i)

    inc %out.3

    if (%out.3 == 4) { var %out.4 = %out.4 $+ mode # +oooo %out.nicks $+ $lf | %out.3 = 0 | %out.nicks = "" }

  }

  if ($nopnick(#,%out.i) == $null) { if ($len(%out.nicks) > 0) var %out.4 = %out.4 $+ mode # +oooo %out.nicks | .quote %out.4 | return }

}

alias munban  {

  :munban

  set %munbannum 1

  :incl

  set %munbantarg $ibl($chan,%munbannum)

  if (%munbantarg == $null) { goto end }

  /mode # -bbbb $ibl($chan,%munbannum) $ibl($chan,$calc(1+ %munbannum )) $ibl($chan,$calc(2+ %munbannum )) $ibl($chan,$calc(3+ %munbannum ))

  inc %munbannum 4 | goto incl

  :end

  unset %munbannum %munbantarg

}

alias opkick {

  :mkick

  if ($opnick(#,0) <= 1) { echo -a .<.There are no users for masskick.->. | halt }

  set %num 1

  :incl

  set %mktarg $opnick(#,%num)

  if (%mktarg == $null) { goto end }

  if ( %nick. [ $+ [ %mktarg ] ] == halt ) { inc %num 1 | goto incl }

  if (%mktarg != $me) && ( $me ison $chan ) && ( $me isop $chan ) { kick # %mktarg You are shit }

  inc %num 1 | goto incl

  :end

  unset %num %mktarg | inc %sdmkicks 1

}

Advertise.mrc 4.12 KB 28.10.10 02:05:47
Antispam.zip 33.76 KB 30.05.11 17:31:54
Auto.mrc 21.66 KB 28.10.10 02:05:48
BLackList.ini 1.91 KB 28.10.10 02:05:49
BanEnfroce.mrc 348 B 28.10.10 02:05:48
JoinfLood.mrc 691 B 28.10.10 02:04:46
MassJoin.mrc 1.19 KB 28.10.10 02:04:48
NickSTyLer.ini 8.14 KB 28.10.10 02:05:54
OpPro.mrc 2.47 KB 28.10.10 02:05:55
Protection.mrc 3.85 KB 14.06.12 10:09:08
Repeat.mrc 2.28 KB 28.10.10 02:04:49
Swear.MRC 4.16 KB 28.10.10 02:04:53
Swear.mrc 35.4 KB 28.10.10 02:05:57
akick.MRC 3.39 KB 28.10.10 02:04:40
caps.mrc 0 B 28.10.10 02:05:48
channelflood.mrc 11.83 KB 28.10.10 02:04:42
clones.mrc 6.24 KB 28.10.10 02:04:43
country.mrc 14.88 KB 28.10.10 02:04:46
kcounter.mrc 2.03 KB 28.10.10 02:04:47
masscmds.ini 2.13 KB 28.10.10 02:05:54
repeat.mrc 3.49 KB 24.10.14 03:47:53
slap.ini 101 B 28.10.10 02:04:50
slap.mrc 9.54 KB 28.10.10 02:04:52
titlebar.mrc 1.28 KB 28.10.10 02:04:54
unrealircop.mrc 7.84 KB 28.10.10 02:04:56